[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26. 表示のカスタマイズ ― 背景色,メニュー (2010/08/21)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=screen%20customize"
"MeadowMemo/表示のカスタマイズ―背景色,メニュー"へのコメント(無し)
検索全文Elisp


この章で紹介していること

まずは, Meadow の各部の名称を理解してください.その上で,自分が設定したいことを 探してみてください (画像で 3 行目の部分を. emacs に追加すると起動時に該当部分を消すこ とができます) .

各部の名前

最新の Meadow/Emacs であれば、 Option (オプション) メニューに「 Show/Hide 」という項目 があり、これを選択することで各部分を表示したり消したりできます。

オプションメニュー

基本的なことは、以下を参考に探してください。



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.1 背景色を変更する (2004/12/21)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=about%20background"
"MeadowMemo/背景色を変更する"へのコメント(無し)
検索全文Elisp

背景色を簡単に変更する方法です.

26.1.1 表示色をテーマのように切り替える− color-theme (2004/12/21)  
26.1.2 色設定を切り替える ― color-mate (2003/03/12)  
26.1.3 バッファの背景色をランダムに変える ― colorful (2003/02/09)  
26.1.4 バッファの背景色をゆっくりと変える ― floatbg (2003/11/05)  
26.1.5 バッファの文字色をゆっくりと変える ― u-color-cycle (2003/11/14)  
26.1.6 偶数行の背景色を変える― stripes (2004/01/24)  
26.1.7 背景色を半透明にする (2005/11/17)  



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.1.1 表示色をテーマのように切り替える− color-theme (2004/12/21)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=color-theme"
"MeadowMemo/表示色をテーマのように切り替える−color-theme"へのコメント(2009/3/6)
検索全文Elisp
要約

Meadow/Emacs の背景や文字の色をテーマのように切り替えることができます.

何が問題なのか?

背景色や文字の色を変えるのは結構面倒なものです.文字の色や各モードの色など一個一 個変えていくのはとても大変です.

また,一度背景色を濃い色に変えてしまうと,明るい背景に変えるのは大変なものです.

何ができるのか?

各色をテーマを選ぶだけで,簡単に選択できます.

設定済みMeadowでは

インストールと設定済みです.

インストール方法

color-theme.el よりダウン ロードして、ロードパスの通ったところへ置きます.

設定方法

以下を.emacsに追加します.

 
(load "color-theme")

詳しい使い方

M-x color-theme- TAB で様々なテーマのリストが表示されます.M-x color-theme-selectとすると一覧が表示され,RETを押すと適用されます.たくさ んのテーマが簡単に切り替えられるので,いろいろと試して一番好きなテーマを探してみ てください.

どれか好きなのがあれば,上の設定に続けて

 
(color-theme-blue-sea)

という風に書いておくと,その設定が起動時から有効になります.気分転換にもいいです よ.

どんな色になるかは、 GNUEmacsColorThemeTest で確認できます。

また,自分が使っている色の設定を書き出すこともできます.M-x color-theme-printです.実行すると,

 
(defun my-color-theme ()
  "Color theme by zzz, created 2003-02-01."
  (interactive)
  (color-theme-install
   '(my-color-theme
     ((background-color . "black")
      (background-mode . dark)
      (border-color . "black")
      (cursor-color . "white")
      (foreground-color . "azure4")
      (frame-background-color . "black")
      (frame-background-mode quote dark)
      (frame-cursor-color . "white")

      以下省略

というものが表示されます.これを.emacs へコピーして,

 
(my-color-theme)

を.emacs に追加すれば,その色設定を使うことができます.

使用されている色の設定をまとめて管理できるし,簡単に色の設定をコピーできるので便 利です.

テーマをランダムに設定

http://www.emacswiki.org/cgi-bin/wiki.pl/ColorTheme より.

以下を.emacs に追加します

 
(funcall (car (nth (random (length color-themes)) color-themes)))

これで起動するたびにテーマが変わります.ただし, initial-frame-alist で背景を設定 していると,そちらが優先されます.

フレームを作るたびに色を変える

http://www.emacswiki.org/cgi-bin/wiki.pl/ColorTheme より.

フレームごとに色を変えた例

C-x 5 2でフレームを作ると各フレーム毎にテーマが設定されます.

 
(setq color-theme-is-global nil)
(defadvice make-frame
  (around ss activate)
  (save-selected-frame
   ad-do-it
   (select-frame ad-return-value)
   (call-interactively (car (nth (random (length color-themes)) color-themes)))))

26.1.1.1 終了時にテーマを保存 (2003/10/25)  



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.1.1.1 終了時にテーマを保存 (2003/10/25)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=save%20color-theme"
"MeadowMemo/終了時にテーマを保存"へのコメント(無し)
検索全文Elisp
要約

color-theme-select で選んだテーマを次回起動時にも利用できるように保存してくれます.

情報源

http://www.emacswiki.org/cgi-bin/wiki.pl/ColorTheme

何が問題なのか?

M-x color-theme-selectでテーマを選ぶことができますが, Meadow を起動し直すと 元のテーマに戻ってしまいます.

もちろんテーマを変えるたびに.emacs も設定し直せばいいのですが,それは面倒です.

何ができるのか?

終了時にテーマを保存し,起動時にそれを復元できます.

設定方法

以下を.emacs の最後の方に追加しておきます.

 
(setq theme-load-from-file t)
(setq theme-default 'color-theme-gnome2)

(defun my-onload()
  (setq filename (concat (expand-file-name "~") "/.curTheme"))
  (if (file-exists-p filename)
      (progn
        (message "selecting theme from .curTheme")
        (load-file filename)
        (color-theme-install (my-color-theme))
        (my-color-theme)
        )
    (funcall theme-default)
    (message "selecting theme from color-theme-standard")
    (color-theme-install (color-theme-standard))
    (color-theme-standard)))

(defun my-kill-saves()
  (if theme-load-from-file
      (progn
        (color-theme-print)
        (write-file  (concat (expand-file-name "~") "/.curTheme")))))

(my-onload)
(add-hook 'kill-emacs-hook 'my-kill-saves)

詳しい使い方

普通に Meadow を使うだけです.これで,自動的に設定が保存され,復元されます.



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.1.2 色設定を切り替える ― color-mate (2003/03/12)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=color-mate"
"MeadowMemo/色設定を切り替える―color-mate"へのコメント(無し)
検索全文Elisp

お勧め度:★★★☆☆.まだあまり設定していなければお勧め.既にいろんな Elisp の設 定を変更していると,いろんな色の設定を背景に合わせて変更せねばならず,結構大変な ので,あまり使えません.

color-theme のように,バッファの背景や文字の色を簡単に変更するものです.使うため には, Color-Mateよ り, color-mate をダウンロードし,解凍します.

そして, bash を起動し,以下のようにします.

./configure --with-emacs=meadow
make
make install

こうすると,適当なフォルダへインストールされるので,これを site-lisp の下へ移動し ます.

設定は付属の Dot.emacs.default を参考にします.

私は, skk-cursor2 がないというエラーが出たので,こんな風に変更しました.

 
(if (and (fboundp 'skk-mode)
         (not (featurep 'xemacs)))
    (require 'skk-cursor))

テーマの設定は最初の方にある

 
(setq color-mate:theme-file "SunnyDay")

を変更すると可能です. theme というフォルダ下にあるファイル名を入れると,次回起動 時に変更してくれます.色が変わらなければ,

 
(setq initial-frame-alist default-frame-alist)

を最後に追加してみてください.



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.1.3 バッファの背景色をランダムに変える ― colorful (2003/02/09)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=colorful"
"MeadowMemo/バッファの背景色をランダムに変える―colorful"へのコメント(無し)
検索全文Elisp

お勧め度:★☆☆☆☆.使ってみると楽しいけど,常用するものではない.バッファ毎に, 自分で設定できると面白いかも.

通常,バッファの背景はすべてのバッファで共通です.そのため,黒に設定すれば,すべ てのバッファが黒になります.

ところが,この Elisp を使うと,背景色がバッファ毎に変わります.何色になるかは乱数 しだい.

使うためには,http://www.geocities.co.jp/SiliconValley-Oakland/7673/より, colorful.el.gz をダウンロードし,解凍します.そして,ロードパスの通ったところへ置 き,以下を.emacs に追加します.

これで,M-x colorful-onとすると,バッファ毎に背景色が変化します.M-x colorful-offでオフになります.

 
(require 'colorful)



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.1.4 バッファの背景色をゆっくりと変える ― floatbg (2003/11/05)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=floatbg"
"MeadowMemo/バッファの背景色をゆっくりと変える―floatbg"へのコメント(無し)
検索全文Elisp

お勧め度:★☆☆☆☆.常用するタイプのものではないけど,おもしろい.

普通,バッファの背景は黒なら黒で固定です.これを,少しずつ変化させてやろうという のが floatbg です.

これを使うと,バッファの背景が徐々に色が変わっていきます.何がうれしいの? と言わ れると,困ってしまいますが,楽しいです.

使うためには, floatbg.elをダウン ロードし,ロードパスの通ったところへ置きます.そして,.emacs に以下を追加します.

細かい数字は試行錯誤してください.これで,M-x floatbg-modeとすると,背景が 変化していきます.再度,M-x floatbg-modeとすると,変化しなくなります.

 
(require 'floatbg)
;; 最初の色を決める. 0 から 1 の間を指定
;; M-x floatbg-reset-initial-values でリセットできる
;; scratch で設定して, M-x floatbg-reset-initial-values として
;; 試すと指定した色に変わる
(setq floatbg-initial-val 0.3)
;; 色を変化させる時間を秒単位で設定する
(setq floatbg-delay 10)
;; 色の変化量を設定.大きいと変化が大きい
(setq floatbg-increment 10)



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.1.5 バッファの文字色をゆっくりと変える ― u-color-cycle (2003/11/14)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=u-color-cycle"
"MeadowMemo/バッファの文字色をゆっくりと変える―u-color-cycle"へのコメント(無し)
検索全文Elisp
要約

バッファの文字色をゆっくりと変えるスクリーンセーバ.編集を開始すると,元の色に戻 ります.

何ができるのか?

バッファの文字の色は普通固定ですが,これをリアルタイムに変えることができます.た だし,編集を開始すると元の色に戻るのでスクリーンセーバのような使い方になります.

インストール方法

u-color-cycle.el.txt をダウンロードし, u-color-cycle.el の名前でロードパスの通ったところへ置きます.

設定方法

常用するものではないので,ファイルを読み込んでM-x eval-bufferだけでいいで しょう.

設定するほども使わないでしょうし.

詳しい使い方

M-x u-color-cycle-windowとします.これで文字の色がリアルタイムで変化します.



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.1.6 偶数行の背景色を変える― stripes (2004/01/24)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=stripes"
"MeadowMemo/偶数行の背景色を変える―stripes"へのコメント(2007/12/28)
検索全文Elisp
要約

偶数行の背景色を変え,全体を捉えやすくすることができます.

何が問題なのか?

全体が一色で,文章が多いと目の移動が飛んでしまうことがあります.その時には,右端 へ戻って,現在行を確認し,次の行を確認し,という視点移動を行う必要があります.

これを防ぐために,一行おきに色が変わっていると,視点の移動が多少楽になります.

何ができるのか?

;;; color-moccur.el
;; -*- Mode: Emacs-Lisp -*-

;;  $Id: screen.texi,v 1.9 2004/01/24 11:04:48 akihisa Exp $

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)

という風に一行おきに色を変えることができます.

とても見難いですね.まぁ、これは冗談にしても、偶数行の背景色を普通の背景色に近い 色にしておくと、少しみやすくなります。

インストール方法

stripes.elをダウンロードし,ロー ドパスの通ったところへ置きます.

設定方法

以下を.emacs に追加します.

 
(require 'stripes)
;; 適当に背景色を指定
(set-face-background 'stripes-face "yellow")

詳しい使い方

M-x turn-on-stripes-modeM-x stripes-modeでオンになります.再度 M-x stripes-modeとするとオフにできます.

コメント

背景色を適切に選択すると,見易く便利になると思います.その場合には各モードの hook に追加するなどして,使うといいでしょう.



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.1.7 背景色を半透明にする (2005/11/17)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=background%20alpha"
"MeadowMemo/背景色を半透明にする"へのコメント(無し)
検索全文Elisp
要約

フレームを半透明にすることができます.

何が問題なのか?

フレームを複数作ると,複数のフレームが重なってしまい,下部にあるソフトなどの表示 が見えなくなります.こういった場合に,アクティブでないフレームだけ半透明にできる と便利です.

何ができるのか?

通常のフレーム,アクティブでないフレーム,移動中のフレーム,サイズ変更中のフレー ムの透明度を変更することができます.

設定済みMeadowでは

設定していません.

インストール方法

基本機能ですので,インストールは不要です.

設定方法

default-frame-alist でフレームサイズを設定しているのであれば,その設定に下記のよ うにパラメータ「alpha」を追加します.数字は前から順に通常のフレーム,アクティブ でないフレーム,移動中のフレーム,サイズ変更中のフレームの透明度になります.透明 度を「nil」にすると,通常の状態になります.

 
(setq default-frame-alist
      (append (list
               '(width . 111)
               '(height . 36)
               '(top . 366)
               '(left . 335)
               '(alpha . (nil 70 50 30))
               )
              default-frame-alist))

下記のようにしても設定できます.

 
(modify-all-frames-parameters
 (list (cons 'alpha  '(nil 70 50 30))))



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.2 文字の色を変更する (2005/03/01)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=about%20foreground"
"MeadowMemo/文字の色を変更する"へのコメント(無し)
検索全文Elisp

文字の色の変更に関連した設定です。

26.2.1 フォントロックの文字色を抑制 (2005/03/01)  



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.2.1 フォントロックの文字色を抑制 (2005/03/01)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=egoge%20wash"
"MeadowMemo/フォントロックの文字色を抑制"へのコメント(無し)
検索全文Elisp
要約

フォントロックの色は結構きつい色になっていることがあるが、色の変化を抑えみやすく できる。

情報源

http://www.emacswiki.org/cgi-bin/wiki.pl/AngryFruitSalad

何が問題なのか?

Emacs のフォントロックの色は

(defun egoge-wash-out-colour (colour)
  "Return a colour string specifying a washed-out version of COLOUR."
  (let ((basec (color-values
                (face-attribute 'default :foreground)))

のように色の変化が大きく、目につらいと感じることがあります。

何ができるのか?

 
(defun egoge-wash-out-colour (colour)
  "Return a colour string specifying a washed-out version of COLOUR."
  (let ((basec (color-values
                (face-attribute 'default :foreground)))

のように、この色変化を小さくして、見易くすることができます。

設定方法

以下を.emacs に追加します

 
(defun egoge-wash-out-colour (colour)
  "Return a colour string specifying a washed-out version of COLOUR."
  (let ((basec (color-values
                (face-attribute 'default :foreground)))
        (list nil))
    (apply 'format "#%02x%02x%02x"
           (dolist (cv (color-values colour) (nreverse list))
             (push (/ (/ (+ cv (* 2 (car basec))) 3) 256) list)))))

 (defun egoge-wash-out-face (face)
  "Make the foreground colour of FACE appear a bit more pale."
  (let ((colour (face-attribute face :foreground)))
    (unless (eq colour 'unspecified)
      (set-face-attribute face nil
                          :foreground (egoge-wash-out-colour colour)))))

 (defun egoge-find-faces (regexp)
  "Return a list of all faces whose names match REGEXP."
  (delq nil
        (mapcar (lambda (face)
                  (and (string-match regexp
                                     (symbol-name face))
                       face))
                (face-list))))

 (when (> (length (defined-colors)) 16)
  (mapc 'egoge-wash-out-face
        (delq 'font-lock-warning-face (egoge-find-faces "^font-lock"))))

詳しい使い方

起動すると、色が変わっているはずです。

うまく動かない

フェイスが定義された後で実行されないと、色は変わりません。そのため、 autoload など で実行しているようなものの色は変化しません。

この場合には、適当な hook に追加するなどの設定が必要です。

フェイスが定義された後でも駄目なようであれば、設定の最後の部分を

 
 (when (> (length (defined-colors)) 16)
  (mapc 'egoge-wash-out-face
        (delq 'font-lock-warning-face (egoge-find-faces ".+"))))

のように変えてみてください。



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.3 タブ (TAB), 全角スペース,改行, EOF を表示する (2008/08/22)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=visualize"
"MeadowMemo/タブ(TAB),全角スペース,改行,EOFを表示する"へのコメント(無し)
検索全文Elisp

タブ, 全角スペース,改行, EOF を表示する方法を紹介します.

26.3.1 タブ, 全角スペースを表示する (2003/10/02)  
26.3.2 改行, EOF を表示 ― dispret (2003/12/28)  
26.3.3 EOF を表示 ― y_eof (2003/07/05)  
26.3.4 全角スペースを表示 − jaspace (2008/08/22)  



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.3.1 タブ, 全角スペースを表示する (2003/10/02)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=visualize%20tab"
"MeadowMemo/タブ,全角スペースを表示する"へのコメント(無し)
検索全文Elisp

お勧め度:★★★★★.これは,常時表示させてます. emacs 雑記に感謝.

タブや全角スペース, 改行直前の半角スペースに色をつける設定で す. emacs 雑記で拾っ たのを使ってます.背景が黒向けの配色なので適当に変更してください.

ただし,これを使うためには,フォントロックが有効になっていることが必要です.

 
;;(defface my-face-r-1 '((t (:background "gray15"))) nil)
(defface my-face-b-1 '((t (:background "gray"))) nil)
(defface my-face-b-2 '((t (:background "gray26"))) nil)
(defface my-face-u-1 '((t (:foreground "SteelBlue" :underline t))) nil)
;;(defvar my-face-r-1 'my-face-r-1)
(defvar my-face-b-1 'my-face-b-1)
(defvar my-face-b-2 'my-face-b-2)
(defvar my-face-u-1 'my-face-u-1)

(defadvice font-lock-mode (before my-font-lock-mode ())
  (font-lock-add-keywords
   major-mode
   '(("\t" 0 my-face-b-2 append)
     (" " 0 my-face-b-1 append)
     ("[ \t]+$" 0 my-face-u-1 append)
     ;;("[\r]*\n" 0 my-face-r-1 append)
     )))
(ad-enable-advice 'font-lock-mode 'before 'my-font-lock-mode)
(ad-activate 'font-lock-mode)

これを設定すると

全角スペース 背景が変わります
________タブはこんな風
行末のスペースはこれ_______

のような画面になります.

この設定のコメントを外すと,行末から次の行までの背景がうっすらと変わります.お手軽に改行を見るにはいいかな.



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.3.2 改行, EOF を表示 ― dispret (2003/12/28)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=dispret"
"MeadowMemo/改行,EOFを表示―dispret"へのコメント(無し)
検索全文Elisp

お勧め度:★☆☆☆☆.私は改行を表示させる必要はないと思うので,使ってません.

Meadow 1.99 でも動きます

改行やファイルの終わり (EOF,end of file) を表示するものです.

http://www.geocities.co.jp/SiliconValley-Oakland/7673/lisp/dispret.el.gzよ りダウンロードして,ロードパスの通ったところへ置き,以下を emacs に追加します.

 
(load "dispret")

これで,M-x dispret-onM-x dispret-offでオン/オフを切り替えます.デフォルトでは改行を<で表示しますが, bitmap.el を使っているなら

 
(setq dispret-eol-string (bitmap-compose "0000007c0404040404040404150E0400"))

という風に設定すると,下のような画面になります

改行を表示しているところ

ただし,ちょっと重いです.



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.3.3 EOF を表示 ― y_eof (2003/07/05)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=yeof"
"MeadowMemo/EOFを表示―y_eof"へのコメント(無し)
検索全文Elisp

お勧め度:★☆☆☆☆.これも必要性を感じないので使っていない.

Meadow 1.99 では動きません

EOF を<EOF>という風に表示してくれます.

y_eof.elをダウン ロードし,.emacs に追加するか,ロードパスの通ったところへ置き,

 
(load "y_eof")

を追加して使ってください.

Meadow 1.99 なら以下のようにすると同じことができるようです.

 
(defun set-buffer-end-mark()
  (let ((overlay (make-overlay (point-max) (point-max))))
    (overlay-put overlay 'before-string #("<EOF>" 0 5 (face highlight)))
    (overlay-put overlay 'insert-behind-hooks
                 '((lambda (overlay after beg end &optional len)
                     (when after
                       (move-overlay overlay (point-max) (point-max))))))))
(add-hook 'find-file-hooks 'set-buffer-end-mark)

あるいは

 
(defun set-buffer-end-mark()
  (let ((overlay (make-overlay (point-max) (point-max))))
    (overlay-put overlay 'before-string #("<EOF>" 0 5 (face highlight)))
    (overlay-put overlay 'insert-behind-hooks
                 '((lambda (overlay after beg end &optional len)
                     (when after
                       (move-overlay overlay (point-max) (point-max))))))))
(add-hook 'find-file-hooks 'set-buffer-end-mark)

でもいい.



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.3.4 全角スペースを表示 − jaspace (2008/08/22)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=jaspace"
"MeadowMemo/全角スペースを表示−jaspace"へのコメント(無し)
検索全文Elisp
要約

全角スペースを強調して表示できる.

何が問題なのか?

通常,全角スペースでも半角スペースでも表示上は区別されないため,どちらなのか分か りません.

何ができるのか?

全角スペースを「□」として表示することで,全角スペースが一目瞭然となります.

設定済みMeadowでは

全角スペースは別の方法で強調するため,これは入れていません.

インストール方法

おまけ for GNU Emacs からダウンロードしてロードパスの通ったところへ置きます.

設定方法

以下を .emacs に追加します.

 
(require 'jaspace)

詳しい使い方

Meadow を再起動すると,全角スペースが強調して表示されます.



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.4 行数・桁数表示関連 (2005/05/22)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=display%20linenum"
"MeadowMemo/行数・桁数表示関連"へのコメント(無し)
検索全文Elisp

行数や桁数を表示するための方法です.

26.4.1 桁数を表示したい ― ruler-mode (2005/01/26)  
26.4.2 行数を表示したい (2003/11/06)  



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.4.1 桁数を表示したい ― ruler-mode (2005/01/26)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=ruler-mode"
"MeadowMemo/桁数を表示したい―ruler-mode"へのコメント(無し)
検索全文Elisp
要約

バッファの先頭に桁数を表示できます.また,現在のカーソル位置もリアルタイムで表示 されます.

何ができるのか?

桁数表示のサンプル

図のように,バッファの先頭に桁数が表示されます.現在,カーソルがある位置が黄色の 線で,折り返し位置が赤の記号で表示されています.

設定済みMeadowでは

Meadow の標準機能なので,そのままで利用できます.

インストール方法

不要です.

設定方法

必要ありません。色設定は M-x list-faces-display で「 ruler 」を探してそのフェ イスを設定すればいいでしょう。

詳しい使い方

M-x ruler-mode とします.これで,表示されます.

必要に応じて

 
(add-hook 'text-mode-hook 'ruler-mode)

などとしておくといいでしょう.



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.4.2 行数を表示したい (2003/11/06)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=line%20number"
"MeadowMemo/行数を表示したい"へのコメント(無し)
検索全文Elisp

お勧め度:モードラインに表示されれば十分なので,使ってません.

Windows の多くのエディタのように行数を表示する方法です.時々動きがあやしかったり するので,無い状態に慣れた方がいいと思います.

26.4.2.1 行数を左に表示する ― wb-line-number.el  
26.4.2.2 vi の set nu のように行数を表示する ― setnu.el (2003/03/14)  



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.4.2.1 行数を左に表示する ― wb-line-number.el

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=wb-line-number"
"MeadowMemo/行数を左に表示する―wb-line-number.el"へのコメント(無し)
検索全文Elisp
http://homepage1.nifty.com/blankspace/emacs/wb-line-number.htmlからダウンロードして, ロードパスの通ったところに置き, 以下を.emacs に追加

 
(setq wb-line-number-scroll-bar t)
(require 'wb-line-number)
(wb-line-number-toggle)

起動すると左に行数が出ているはずです. ただし, 常に出ているので, 出て欲しくない時はM-x wb-line-number-toggleでオン/オフを切り替えましょう.



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.4.2.2 vi の set nu のように行数を表示する ― setnu.el (2003/03/14)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=setnu"
"MeadowMemo/viのsetnuのように行数を表示する―setnu.el"へのコメント(無し)
検索全文Elisp

vi like に行を表示する elisp です.http://www.anc.ed.ac.uk/~stephen/emacs/ell.htmlから setnu.el をダウンロードし,ロードパスの通ったところへ置き,以下を.emacs に追加します

 
(load "setnu")

M-x setnu-modeでオン/オフの切り替えができます.

この setnu はたまに表示が乱れたりします.このバグを修正したものとして, setnu+.el が あります.これは, setnu-plus.elにありますので, ダウンロードして,ロードパスの通ったところへ置きます.そして, setnu の設定の後に, 以下を追加します.使い方などは全く変わりません,

 
(load "setnu-plus")



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.5 メニュー関連 (2005/05/22)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=customize%20menu"
"MeadowMemo/メニュー関連"へのコメント(無し)
検索全文Elisp

ここでは,メニューに関連したカスタマイズを紹介します.

26.5.1 メニューを日本語にしたい ― menu-tree (2005/05/22)  



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.5.1 メニューを日本語にしたい ― menu-tree (2005/05/22)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=menu%20tree"
"MeadowMemo/メニューを日本語にしたい―menu-tree"へのコメント(無し)
検索全文Elisp
要約

File や Buffers といった基本的なメニューを日本語にすることができます.

情報源

Hena Hena Nikkiと Wiki への 書き込み.

何が問題なのか?

Meadow を起動すると,様々なメニューがあります.しかし,これらはすべて英語なので, 分かりにくいものもあります.

何ができるのか?

File や Buffers などのメニューを日本語にすることができます.

日本語化されたメニュー

インストール方法

patch のページから emacs-21.2_jpmenu.tar.gz をダウンロードし,解凍します.

その中に menu-tree.el というファイルがあるので,これをロードパスの通ったところへ置 きます.

設定方法

以下を.emacs に追加します.

 
(require 'menu-tree)

詳しい使い方

Meadow を起動するとメニューが日本語になります.

26.5.1.1 メニューにファイル名を表示 ― a-menu (2005/05/22)  



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.5.1.1 メニューにファイル名を表示 ― a-menu (2005/05/22)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=a-menu"
"MeadowMemo/メニューにファイル名を表示―a-menu"へのコメント(無し)
検索全文Elisp
要約

メニューに指定したディレクトリのファイル名を追加することで,メニューを選択するだ けで,簡単にファイルを読み込ませるようにする.

何が問題なのか?

普段使わない機能や Elisp をすべて読み込ませると起動が遅くなります.

何ができるのか?

メニューに指定したディレクトリのファイル名を追加することができます.これにより, そのファイル名を選択するだけで,そのファイルを読み込ませることができます.

設定済みMeadowでは

インストールしていません.

インストール方法

http://home.att.ne.jp/alpha/z123/elisp-e.html からダウンロードして,ロー ドパスの通ったところに追加します.

設定方法

以下を参考に .emacs に追加します.

 
(require 'a-menu)
(a-menu "~/mylisp")

詳しい使い方

これで,起動すると,メニューに上記の設定例であれば「mylisp」というメニューが表示 されます.

そのメニューを選択すると,そのディレクトリ下にあるファイル名が表示されます(ただし, 拡張子が el のもののみです).どれかを選ぶと,そのファイルが読み込まれます.

うまく動かない

日本語のファイルはうまく動かない場合があります.



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.6 モードライン関連 (2010/08/21)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=customize%20mode-line"
"MeadowMemo/モードライン関連"へのコメント(無し)
検索全文Elisp

モードラインに関連したカスタマイズを紹介します.

26.6.1 モードラインを隠す (2003/11/03)  
26.6.2 カーソル位置をモードラインに表示 − sml-modeline (2010/08/21)  



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.6.1 モードラインを隠す (2003/11/03)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=mode-line-hack"
"MeadowMemo/モードラインを隠す"へのコメント(無し)
検索全文Elisp

要約

画面最下部のモードラインを隠すことができます。ただし、ヘッダラインは追加されます。

何ができるのか?

モードラインを隠した画面

のようにモードラインを隠すことができます。

インストール方法

ロードパスの通ったところへ置きます

設定方法

以下を.emacs に追加します。

 
(require 'mode-line-hack)

詳しい使い方

起動すると、モードラインが消えます。



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.6.2 カーソル位置をモードラインに表示 − sml-modeline (2010/08/21)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=sml-modeline"
"MeadowMemo/カーソル位置をモードラインに表示−sml-modeline"へのコメント(無し)
検索全文Elisp
要約

モードラインにカーソル位置を分かりやすく表示できます.

情報源

モードラインにスクロールバーぽい表示をしてくれる sml-modeline。CommentsAdd Stark1LoW で見ました.

何が問題なのか?

モードラインを見ても,いまいち,カーソルが全体のどの辺にあるのか分かりません

何ができるのか?

モードラインにカーソル位置を表示

図のように,モードラインにカーソル位置があるエリアを視覚的に表示してくれます.

設定済み Meadow では

インストールしていません.

インストール方法

sml-modeline.el の内容をコピーして,sml-modeline.el として,ロードパスの通ったところに置きます.

設定方法

下記を .emacs に追加します.

 
(load "sml-modeline.el")
(sml-mode t)

詳しい使い方

Meadow/Emacs を再起動すれば,自動的に表示されているはずです.

コメント

なかなか発想は面白いですね.



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.7 ツールバー関連 (2004/10/31)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=toolbar"
"MeadowMemo/ツールバー関連"へのコメント(無し)
検索全文Elisp

26.7.1 一時的にツールバーを隠す (2004/10/31)  



[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [表紙] [目次] [索引] [検索] [上端 / 下端] [?]

26.7.1 一時的にツールバーを隠す (2004/10/31)

URL="http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=invisible%20toolbar"
"MeadowMemo/一時的にツールバーを隠す"へのコメント(無し)
検索全文Elisp
要約

通常はツールバーを隠しておき,ツールバーというメニューを押した時だけツールバーを 表示させる.

情報源

http://thread.gmane.org/gmane.emacs.sources/997

何が問題なのか?

ツールバーは結構大きくて常に表示しておくのは邪魔なものです.

何ができるのか?

通常はツールバーを隠しておき,好きな時だけツールバーを表示させることができます.

設定方法

以下を.emacsに追加します.

 
;;; tool-bar+.el --- Extensions to standard library tool-bar.el
;;
;; Filename: tool-bar+.el
;; Description: Extensions to standard library tool-bar.el
;; Author: Drew Adams
;; Maintainer: Drew Adams
;; Copyright (C) 2004, Drew Adams, all rights reserved.
;; Created: Tue Oct 05 17:02:16 2004
;; Version: 21.0
;; Last-Updated: Sun Oct 10 21:41:05 2004
;;           By: dradams
;;     Update #: 163
;; Keywords: tool-bar, convenience, mouse, button, frame
;; Compatibility: GNU Emacs 21.x
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;;; Commentary: Extensions to standard library tool-bar.el
;;
;;
;;  New commands defined here:
;;
;;    `show-tool-bar-for-one-command', `tool-bar-here-mode',
;;    `tool-bar-pop-up-mode'.
;;
;;
;;  New key bound here: [menu-bar pop-up-tool-bar]
;;
;;
;;  Usage:
;;
;;    Load this library: (require 'tool-bar+).
;;    Turn on tool-bar pop-up mode: M-x tool-bar-pop-up-mode.
;;
;;    Click "Buttons" in the menu-bar to access the tool-bar when you
;;    need it. This displays the tool-bar buttons just long enough for
;;    one command: after you click a tool-bar button, the tool-bar
;;    disappears again.
;;
;;    The advantage of `tool-bar-pop-up-mode' is that you do not lose
;;    frame real estate to the tool-bar -- you have it when you need
;;    it, at the cost of an extra click ("Buttons").
;;
;;    In addition to defining minor mode `tool-bar-pop-up-mode', this
;;    library defines minor mode `tool-bar-here-mode', which is the
;;    same as the global `tool-bar-mode' except that it affects only
;;    the current frame.
;;
;;    The advantage of `tool-bar-here-mode' is (again) that it saves
;;    real estate on frames other than the ones with the tool-bar.
;;
;;
;;  Put this in your initialization file (`~/.emacs'):
;;
;;  (require 'tool-bar+) ; load this library
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;;; Change log:
;;
;; 2004/10/10 dadams
;;
;;     Added condition-case in show-tool-bar-for-one-command.
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;;; Code:


;;; Local Tool Bar Mode -------------------------

(define-minor-mode tool-bar-here-mode
  "Toggle use of the tool bar on this frame only.
With numeric ARG, display the tool bar if and only if ARG is positive.

See `tool-bar-add-item' and `tool-bar-add-item-from-menu' for
conveniently adding tool bar items."
  :init-value nil :global t :group 'mouse :group 'frames
  (and (display-images-p)
       (let ((lines (if tool-bar-here-mode 1 0)))
         ;; Alter existing frame...
         (modify-frame-parameters (selected-frame) (list (cons 'tool-bar-lines
                                                               lines))))
       (if (and tool-bar-here-mode
                (display-graphic-p)
                (= 1 (length (default-value 'tool-bar-map)))) ; not yet set up
           (tool-bar-setup))))

(make-variable-frame-local 'tool-bar-here-mode)


;;; Pop-Up Tool Bar Mode ------------------------

;; If either of the normal tool-bar modes is turned on, then
;; `tool-bar-popup-mode' is not available.
(define-key global-map [menu-bar pop-up-tool-bar]
  '(menu-item
    "Buttons" show-tool-bar-for-one-command
    :visible (and tool-bar-pop-up-mode (not tool-bar-mode) (not
                                                            tool-bar-here-mode))
    :enable  (and tool-bar-pop-up-mode (not tool-bar-mode) (not
                                                            tool-bar-here-mode))
    :help "Use tool bar for one command"))

(setq menu-bar-final-items (append menu-bar-final-items (list
                                                         'pop-up-tool-bar)))

(define-minor-mode tool-bar-pop-up-mode
  "Toggle tool-bar pop-up.
With numeric ARG, turn on tool-bar pop-up if and only if ARG is positive.

Note: Command `tool-bar-pop-up-mode' functions as a toggle only
      if neither `tool-bar-mode' nor `tool-bar-here-mode' is on.

      If either of those modes is on, then command
      `tool-bar-pop-up-mode' turns them both off and turns
      `tool-bar-pop-up-mode' on."
  :init-value nil :global t :group 'mouse :group 'frames
  (when (or tool-bar-mode tool-bar-here-mode)
    (setq tool-bar-pop-up-mode t)
    (tool-bar-mode -99)
    (tool-bar-here-mode -99)))

;; Note: This treats mouse events specially: it scrolls the buffer
;; text (window) down to compensate for the disappearance of the
;; tool-bar.  That is, it replaces the tool-bar with an equivalent
;; number of lines of buffer text.
;;
;; This is so that the place where you click the mouse when the
;; tool-bar is visible corresponds to the place where the mouse is
;; after the tool-bar disappears. Otherwise, the buffer text moves up,
;; relative to the mouse, and a region is selected (without ever
;; physically moving the mouse).
;;
(defun show-tool-bar-for-one-command ()
  "Pop up the tool bar so you can click a button.
The tool bar stays visible until one command is executed
\(whether or not it was initiated by clicking a button)."
  (interactive)
  (unless tool-bar-pop-up-mode
    (error "You must turn on `tool-bar-pop-up-mode' to use this command"))
  (let (evnt tb-lines)
    (unwind-protect
        (progn
          (tool-bar-here-mode 99)       ; Show tool-bar
          (setq evnt (read-event))
          (push evnt unread-command-events))
      (when (and (consp evnt)
                 (member (event-basic-type (car evnt)) '(mouse-1 mouse-2
                                                                 mouse-3)))
        (setq tb-lines (cdr (assq 'tool-bar-lines (frame-parameters
                                                   (selected-frame)))))
        (condition-case nil
            (when tb-lines (scroll-down tb-lines))
          (error (tool-bar-here-mode -99)))) ; E.g. "Beginning of buffer"
      (tool-bar-here-mode -99))))       ; Hide tool-bar


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

(provide 'tool-bar+)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; tool-bar+.el ends here

詳しい使い方

M-x tool-bar-pop-up-mode でオンにします.

これで、通常はツールバーが非表示となります。メニューに「 Tool Bar 」が追加されてお り、これを選択するとツールバーが表示されます。

ツールバーが表示されても,バッファをマウスでクリックすると,ツールバーは消えます.


[ << ] [ >> ]           [表紙] [目次] [索引] [検索] [上端 / 下端] [?]